/* -*- Mode: C++; tab-width: 2; indent-tabs-mode: nil; c-basic-offset: 2 -*- */
/* ***** BEGIN LICENSE BLOCK *****
 * Version: MPL 1.1/GPL 2.0/LGPL 2.1
 *
 * The contents of this file are subject to the Mozilla Public License Version
 * 1.1 (the "License"); you may not use this file except in compliance with
 * the License. You may obtain a copy of the License at
 * http://www.mozilla.org/MPL/
 *
 * Software distributed under the License is distributed on an "AS IS" basis,
 * WITHOUT WARRANTY OF ANY KIND, either express or implied. See the License
 * for the specific language governing rights and limitations under the
 * License.
 *
 * The Original Code is mozilla.org code.
 *
 * The Initial Developer of the Original Code is
 * Netscape Communications Corporation.
 * Portions created by the Initial Developer are Copyright (C) 2002
 * the Initial Developer. All Rights Reserved.
 *
 * Contributor(s):
 *   Simon Fraser <sfraser@netscape.com>
 *
 * Alternatively, the contents of this file may be used under the terms of
 * either the GNU General Public License Version 2 or later (the "GPL"), or
 * the GNU Lesser General Public License Version 2.1 or later (the "LGPL"),
 * in which case the provisions of the GPL or the LGPL are applicable instead
 * of those above. If you wish to allow use of your version of this file only
 * under the terms of either the GPL or the LGPL, and not to allow others to
 * use your version of this file under the terms of the MPL, indicate your
 * decision by deleting the provisions above and replace them with the notice
 * and other provisions required by the GPL or the LGPL. If you do not delete
 * the provisions above, a recipient may use your version of this file under
 * the terms of any one of the MPL, the GPL or the LGPL.
 *
 * ***** END LICENSE BLOCK ***** */
 
#import "JSConsole.h"
#import "NSString+Gecko.h"

#import "CHBrowserService.h"

#include "nsString.h"
#include "nsIServiceManager.h"
#include "nsIConsoleService.h"
#include "nsIConsoleListener.h"

/* Header file */
class nsConsoleListener : public nsIConsoleListener
{
public:
  NS_DECL_ISUPPORTS
  NS_DECL_NSICONSOLELISTENER
  
  nsConsoleListener();
  virtual ~nsConsoleListener();

protected:
  
};

NS_IMPL_ISUPPORTS1(nsConsoleListener, nsIConsoleListener)

nsConsoleListener::nsConsoleListener()
{
}

nsConsoleListener::~nsConsoleListener()
{
}

/* void observe (in nsIConsoleMessage aMessage); */
NS_IMETHODIMP nsConsoleListener::Observe(nsIConsoleMessage* aMessage)
{
  if (aMessage) {
    nsAutoString msgBuffer;
    aMessage->GetMessageMoz(getter_Copies(msgBuffer));
    [[JSConsole sharedJSConsole] logMessage:[NSString stringWith_nsAString:msgBuffer]];
  }
  
  return NS_OK;
}

/* End of implementation class template. */

#pragma mark -

@interface JSConsole(Private)

- (void)setupConsoleListener;
- (void)cleanupConsoleService;

- (void)registerNotificationListener;
- (void)shutdown: (NSNotification*)aNotification;

@end


@implementation JSConsole

static JSConsole* gJSConsole;

+ (JSConsole*)sharedJSConsole
{
  if (!gJSConsole)
    gJSConsole = [[JSConsole alloc] init];
  
  return gJSConsole;
}

- (id)init
{
  if ((self = [super init])) {
    [self registerNotificationListener];
    [self setupConsoleListener];
  }
  return self;
}

- (void)dealloc
{
  if (self == gJSConsole)
    gJSConsole = nil;

  [[NSNotificationCenter defaultCenter] removeObserver:self];
  NS_IF_RELEASE(mConsoleListener);
  [super dealloc];
}

- (void)logMessage:(NSString*)message
{
  NSLog(@"JS error: %@", message);
}

// gets called before XPCOM shutdown
- (void)cleanupConsoleService
{
  if (mConsoleListener) {
    nsCOMPtr<nsIConsoleService> consoleService = do_GetService(NS_CONSOLESERVICE_CONTRACTID);
    if (consoleService)
      consoleService->UnregisterListener(mConsoleListener);
      
    NS_RELEASE(mConsoleListener);  // nulls it out
  }
}

- (void)setupConsoleListener
{
  mConsoleListener = new nsConsoleListener;
  NS_IF_ADDREF(mConsoleListener);
  
  nsCOMPtr<nsIConsoleService> consoleService = do_GetService(NS_CONSOLESERVICE_CONTRACTID);
  if (consoleService)
    consoleService->RegisterListener(mConsoleListener);
}

- (void)registerNotificationListener
{
  [[NSNotificationCenter defaultCenter] addObserver:self
                                           selector:@selector(shutdown:)
                                               name:TermEmbeddingNotificationName
                                             object:nil];
}

- (void)shutdown:(NSNotification*)aNotification
{
  [self cleanupConsoleService];
  [gJSConsole autorelease];
}

@end
